0cb313f7cb
As discussed in libc-alpha [1] current clone with CLONE_VM (without
CLONE_THREAD set) will reset the pthread pid/tid fields to -1. The
issue is since memory is shared between the parent and child it will
clobber parent's cached pid/tid leading to internal inconsistencies
if the value is not restored.
And even it is restored it may lead to racy conditions when between
set/restore a thread might invoke pthread function that validate the
pthread with INVALID_TD_P/INVALID_NOT_TERMINATED_TD_P and thus get
wrong results.
As stated in BZ19957, previously reports of this behaviour was close
with EWONTFIX due the fact usage of clone outside glibc is tricky
since glibc requires consistent internal pthread, while using clone
directly may not provide it. However since now posix_spawn uses
clone (CLONE_VM) to fixes various issues related to previous vfork
usage this issue requires fixing.
The vfork implementation also does something similar, but instead
it negates and restores only the *pid* field and functions that
might access its value know to handle such case (getpid, raise
and pthread ones that uses INVALID_TD_P/INVALID_NOT_TERMINATED_TD_P
macros that check only *tid* field). Also vfork does not call
__clone directly, instead calling either __NR_vfork or __NR_clone
directly.
So this patch removes this clone behavior by avoiding setting
the pthread pid/tid field for CLONE_VM. There is no need to
check for CLONE_THREAD, since the minimum supported kernel in all
architecture implies that CLONE_VM must be used with CLONE_THREAD,
otherwise clone returns EINVAL.
Instead of current approach of:
int clone(int (*fn)(void *), void *child_stack, int flags, ...)
[...]
if (flags & CLONE_THREAD)
goto do_syscall;
pid_t new_value;
if (flags & CLONE_VM)
new_value = -1;
else
new_value = getpid ();
THREAD_SETMEM (THREAD_SELF, pid, new_value);
THREAD_SETMEM (THREAD_SELF, tid, new_value);
do_syscall:
[...]
The new approach uses:
int clone(int (*fn)(void *), void *child_stack, int flags, ...)
[...]
if (flags & CLONE_VM)
goto do_syscall;
pid_t new_value = getpid ();
THREAD_SETMEM (THREAD_SELF, pid, new_value);
THREAD_SETMEM (THREAD_SELF, tid, new_value);
do_syscall:
[...]
It also removes the linux tst-getpid2.c test which expects the previous
behavior and instead add another clone test.
Tested on x86_64, i686, x32, powerpc64le, aarch64, armhf, s390, and
s390x. I also did limited check on mips32 and sparc64 (using the new
added test).
I also got reviews from both m68k, hppa, and tile. So I presume for
these architecture the patch works.
The fixes for alpha, microblaze, sh, ia64, and nio2 have not been
tested.
[1] https://sourceware.org/ml/libc-alpha/2016-04/msg00307.html
* sysdeps/unix/sysv/linux/Makefile [$(subdir) == nptl] (test): Remove
tst-getpid2.
(test): Add tst-clone2.
* sysdeps/unix/sysv/linux/tst-clone2.c: New file.
* sysdeps/unix/sysv/linux/aarch64/clone.S (__clone): Do not change
pid/tid fields for CLONE_VM.
* sysdeps/unix/sysv/linux/arm/clone.S: Likewise.
* sysdeps/unix/sysv/linux/i386/clone.S: Likewise.
* sysdeps/unix/sysv/linux/mips/clone.S: Likewise.
* sysdeps/unix/sysv/linux/powerpc/powerpc32/clone.S: Likewise.
* sysdeps/unix/sysv/linux/powerpc/powerpc64/clone.S: Likewise.
* sysdeps/unix/sysv/linux/s390/s390-32/clone.S: Likewise.
* sysdeps/unix/sysv/linux/s390/s390-64/clone.S: Likewise.
* sysdeps/unix/sysv/linux/sparc/sparc32/clone.S: Likewise.
* sysdeps/unix/sysv/linux/sparc/sparc64/clone.S: Likewise.
* sysdeps/unix/sysv/linux/x86_64/clone.S: Likewise.
* sysdeps/unix/sysv/linux/tst-getpid2.c: Remove file.
125 lines
3.3 KiB
ArmAsm
125 lines
3.3 KiB
ArmAsm
/* Copyright (C) 1996-2016 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
Contributed by Andreas Schwab (schwab@issan.informatik.uni-dortmund.de)
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library. If not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
/* clone() is even more special than fork() as it mucks with stacks
|
|
and invokes a function in the right context after its all over. */
|
|
|
|
#include <sysdep.h>
|
|
#define _ERRNO_H 1
|
|
#include <bits/errno.h>
|
|
#include <tls.h>
|
|
|
|
#define CLONE_VM 0x00000100
|
|
|
|
/* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
|
|
void *parent_tidptr, void *tls, void *child_tidptr) */
|
|
|
|
.text
|
|
ENTRY (__clone)
|
|
|
|
/* Sanity check arguments. */
|
|
movel #-EINVAL, %d0
|
|
movel 4(%sp), %a0 /* no NULL function pointers */
|
|
tstl %a0
|
|
jeq SYSCALL_ERROR_LABEL
|
|
movel 8(%sp), %a1 /* no NULL stack pointers */
|
|
tstl %a1
|
|
jeq SYSCALL_ERROR_LABEL
|
|
|
|
/* Allocate space and copy the argument onto the new stack. */
|
|
movel 16(%sp), -(%a1)
|
|
|
|
/* Do the system call */
|
|
movel 12+0(%sp), %d1 /* get flags */
|
|
movel %d3, -(%a1) /* save %d3 and get parent_tidptr */
|
|
movel %d3, -(%sp)
|
|
cfi_adjust_cfa_offset (4)
|
|
cfi_rel_offset (%d3, 0)
|
|
movel 20+4(%sp), %d3
|
|
movel %d4, -(%a1) /* save %d4 and get child_tidptr */
|
|
movel %d4, -(%sp)
|
|
cfi_adjust_cfa_offset (4)
|
|
cfi_rel_offset (%d4, 0)
|
|
movel 28+8(%sp), %d4
|
|
movel %d5, -(%a1) /* save %d5 and get tls */
|
|
movel %d5, -(%sp)
|
|
cfi_adjust_cfa_offset (4)
|
|
cfi_rel_offset (%d5, 0)
|
|
movel 24+12(%sp), %d5
|
|
/* save %d2 and get stack pointer */
|
|
#ifdef __mcoldfire__
|
|
movel %d2, -(%a1)
|
|
movel %d2, -(%sp)
|
|
cfi_adjust_cfa_offset (4)
|
|
cfi_rel_offset (%d2, 0)
|
|
movel %a1, %d2
|
|
#else
|
|
exg %d2, %a1 /* save %d2 and get stack pointer */
|
|
cfi_register (%d2, %a1)
|
|
#endif
|
|
movel #SYS_ify (clone), %d0
|
|
|
|
/* End FDE now, because in the child the unwind info will be
|
|
wrong. */
|
|
cfi_endproc
|
|
|
|
trap #0
|
|
#ifdef __mcoldfire__
|
|
movel (%sp)+, %d2
|
|
#else
|
|
exg %d2, %a1 /* restore %d2 */
|
|
#endif
|
|
movel (%sp)+, %d5 /* restore %d5, %d4 and %d3 */
|
|
movel (%sp)+, %d4
|
|
movel (%sp)+, %d3
|
|
|
|
tstl %d0
|
|
jmi SYSCALL_ERROR_LABEL
|
|
jeq thread_start
|
|
|
|
rts
|
|
|
|
thread_start:
|
|
cfi_startproc
|
|
cfi_undefined (pc) /* Mark end of stack */
|
|
subl %fp, %fp /* terminate the stack frame */
|
|
/* Check and see if we need to reset the PID. */
|
|
andl #CLONE_VM, %d1
|
|
jne donepid
|
|
movel #SYS_ify (getpid), %d0
|
|
trap #0
|
|
movel %a0, -(%sp)
|
|
movel %d0, -(%sp)
|
|
bsrl __m68k_read_tp@PLTPC
|
|
movel (%sp)+, %d0
|
|
movel %d0, PID_OFFSET(%a0)
|
|
movel %d0, TID_OFFSET(%a0)
|
|
movel (%sp)+, %a0
|
|
donepid:
|
|
jsr (%a0)
|
|
movel %d0, %d1
|
|
movel #SYS_ify (exit), %d0
|
|
trap #0
|
|
cfi_endproc
|
|
|
|
cfi_startproc
|
|
PSEUDO_END (__clone)
|
|
|
|
libc_hidden_def (__clone)
|
|
weak_alias (__clone, clone)
|